Vsebina

# Funkcije preglednice

Ta razdelek vsebuje opise funkcij preglednice skupaj s primerom.

Za dostop do tega ukaza ...

Vstavi – Funkcija – Kategorija Preglednica

## ERROR.TYPE

Vrne število, ki predstavlja določeno vrsto napake, ali vrednost napake #N/A, če ne gre za napako.

## STYLE

Uveljavi slog v celici, ki vsebuje formulo.

## ADDRESS

Vrne naslov celice (sklic) v obliki besedila glede na navedene številke vrstic in stolpcev. Izbirno lahko določite, če bo naslov naveden kot absolutni naslov (npr. $A$1) ali relativno (kot A1) ali v mešani obliki (A$1 ali $A1). Tukaj lahko določite tudi ime delovnega lista.

Zaradi prenosljivosti funkciji ADDRESS in INDIRECT podpirata neobvezen parameter, ki določa, ali naj bo namesto običajne notacije A1 uporabljena notacija naslavljanja celic V1S1.

Pri ADDRESS je parameter vstavljen kot četrti parameter, ki zamakne neobvezen parameter imena delovnega lista na peti položaj.

Pri INDIRECT je parameter dodan kot drug parameter.

Pri obeh funkcijah velja, da je ob argumentu z vrednostjo 0 uporabljena notacija V1S1. Če argument ni podan ali ima vrednost, različno od 0, je uporabljena notacija A1.

V primeru notacije V1S1 funkcija ADDRESS vrne nize naslovov s klicajem »!« kot ločilom imen delovnih listov, funkcija INDIRECT pa pričakuje klicaj kot ločilo imen delovnih listov. Obe funkciji še vedno uporabljata piko ».« kot ločilo med imeni delovnih listov v notaciji A1.

Ko odpirate dokumente v zapisu ODF 1.0/1.1, bo v funkcijah ADDRESS, ki prikazujejo ime delovnega lista kot četrti parameter, to ime delovnega lista pomaknjeno v peti parameter. Na mesto četrtega parametra bo vstavljena vrednost 1.

Če funkcije ADDRESS uporabljajo četrti parameter, bo pri shranjevanju v zapisu ODF 1.0/1.1 ta parameter odstranjen.

Preglednice ne shranjujte v starem zapisu ODF 1.0/1.1, če ste uporabili novi četrti parameter funkcije ADDRESS z vrednostjo 0.

Funkcija INDIRECT se shrani brez pretvorbe v zapis ODF 1.0/1.1. Če je bil prisoten drug parameter, bo starejša različica modula Calc vrnila za to funkcijo napako.

#### Skladnja

ADDRESS(vrstica; stolpec [; Abs [; A1 [; "delovni_list"]]])

vrstica predstavlja številko vrstice za sklic na celico

stolpec je številka stolpca sklica na celico (številka, ne črka)

Abs določa vrsto sklica:

1: absolutno ($A$1)

2: sklic vrstice je absoluten; sklic stolpca je relativen (A$1)

3: sklic vrstice je relativen; sklic stolpca je absoluten ($A1)

4: relativno (A1)

A1 (neobvezno) – če ima vrednost 0, je uporabljena oblika zapisa V1S1. Če tega parametra ni ali ima drugačno vrednost kot 0, je uporabljena notacija A1.

Delovni_list je ime delovnega lista. Ime mora biti postavljeno pod dvojne navedke.

### Primer:

=ADDRESS(1;1;2;"DelovniList2") vrne: DelovniList2.A$1

Če je gornja formula v celici B2 trenutnega delovnega lista in celica A1 na delovnem listu 2 vsebuje vrednost -6, se lahko na izbrano celico posredno skličete z uporabo funkcije v B2 tako, da vnesete =ABS(INDIRECT(B2)). Rezultat je absolutna vrednost sklica celice, določenega v B2; kar je v tem primeru 6.

## AREAS

Vrne število območij v sklicu. Območje je lahko obseg stičnih celic ali pa ena celica.

Funkcija pričakuje en sam argument. Če navedete več obsegov, jih morate obdati z dodatnimi oklepaji. Več obsegov lahko vnesete z uporabo podpičja (;) v vlogi ločila, vendar se le-to ponavadi pretvori v operator tilda (~). Slednja se uporablja za spajanje obsegov.

#### Skladnja

AREAS(Sklic)

Sklic je sklic na celico ali obseg celic.

#### Primer

=AREAS(A1:B3;F2;G1) vrne 3, ker gre za sklic na tri celice in/ali območja. Po vnosu se to pretvori v =AREAS((A1:B3~F2~G1)).

=AREAS(Vse) vrne 1, če ste v Podatki – Določi obseg določili območje z imenom Vse.

## CHOOSE

Vrne vrednost s seznama, na katerem je lahko navedenih do 30 vrednosti.

#### Skladnja

CHOOSE(kazalo; vrednost 1 [; vrednost 2 [; ... [; vrednost 30]]])

Kazalo je sklic ali število med 1 in 30, ki določa, katero vrednost mora funkcija izbrati s seznama.

Vrednost 1, vrednost 2, ..., vrednost 30 je seznam vrednosti, ki so vnesene kot sklic na celico ali kot posamezne vrednosti.

#### Primer

=CHOOSE(A1;B1;B2;B3;"Danes";"Včeraj";"Jutri") npr. pri vrednosti A1 = 2 vrne vsebino celice B2; pri A1 = 4 funkcija vrne besedilo »Danes«.

## COLUMN

Vrne številko stolpca sklica. Če je sklic celica, vrne številko stolpca celice; če je vrednost območje celic, vrne ustrezne številke stolpcev v obliki enovrstične matrike, če je formula vnesena kot matrična formula. Če funkcije COLUMN s parametrom sklica na območje ne uporabljamo za matrično formulo, funkcija vrne le številko stolpca prve celice znotraj območja.

#### Skladnja

COLUMN([sklic])

Sklic je sklic na celico ali območje celic, katerih prvo številko stolpca želimo najti.

Če ne vnesete sklica, funkcija vrne številko stolpca celice, v katero je vnešena formula. LibreOffice Calc samodejno nastavi sklic na trenutno celico.

#### Primer

=COLUMN(A1) je enako 1. Stolpec A je prvi stolpec v tabeli.

=COLUMN(C3:E3) je enako 3. Stolpec C je tretji stolpec v tabeli.

=COLUMN(D3:G10) vrne 4, ker je stolpec D četrti stolpec v tabeli in funkcija COLUMN ni uporabljena kot matrična formula (v tem primeru je kot rezultat vedno uporabljena prva vrednost matrike).

{=COLUMN(B2:B7)} in =COLUMN(B2:B7) oba vrneta 2, ker sklic vsebuje le stolpec B kot drugi stolpec v tabeli. Ker imajo območja, ki se nahajajo v enem stolpcu, le eno številko stolpca, se nič ne spremeni, če je formula uporabljena kot matrična formula.

=COLUMN() vrne 3, če formulo vnesete v stolpec C.

{=COLUMN(Zajec)} vrne enovrstično matriko (3, 4) če je »Zajec« ime območja (C1:D3).

## COLUMNS

Vrne število stolpcev v določenem sklicu.

#### Skladnja

COLUMNS(matrika)

Polje je sklic na obseg celic, katerih skupno število stolpcev želimo najti. Argument je lahko tudi posamezna celica.

#### Primer

=COLUMNS(B5) vrne 1, ker celica vsebuje le en stolpec.

=COLUMNS(A1:C5) je enako 3. Sklic obsega tri stolpce.

=COLUMNS(Zajec) vrne 2, če je Zajec ime območja (C1:D3).

## DDE

Vrne rezultat na osnovi DDE povezave. Če se vsebina območja, na katerega se nanaša sklic, spremeni, se spremeni tudi vrednost, ki jo vrne formula. Preglednico morate ponovno zagnati ali izbrati Uredi – Povezave, da lahko vidite posodobljeno povezavo. Povezave med različnimi operacijskimi sistemi niso dovoljene. V LibreOffice, ki je npr. nameščen na računalniku z operacijskim sistemom Windows, ne moremo ustvariti povezave z datoteko, ki je bila ustvarjena na računalniku z operacijskim sistemom Linux.

#### Skladnja

DDE("strežnik"; "datoteka"; "obseg" [; način])

strežnik je ime strežniškega programa. Programi LibreOffice imajo strežniško ime »soffice«.

Datoteka je celotno ime datoteke, vključno z njeno potjo.

Obseg je območje, ki vsebuje podatke, ki jih želimo obdelati.

Način je neobvezni parameter, ki nadzira način, kako DDE-strežnik pretvori svoje podatke v števila.

Način | Učinek
--- | ---
0 ali izpuščen | Oblika številk iz sloga celic »Privzeto«
1 | Podatki so vedno podani v standardni obliki ameriške angleščine
2 | Podatki se preberejo kot besedilo, ne pretvorijo se v številke

#### Primer

=DDE("soffice";"c:\office\document\podatki1.ods";"DelovniList1.A1") prebere vsebino celice A1 na DelovnemListu1 preglednice LibreOffice Calc podatki1.ods.

=DDE("soffice";"c:\office\document\moto.ods";"Današnji moto") v celico, ki vsebuje to formulo, vpiše moto. Najprej morate vnesti vrstico v dokument moto.ods, ki vsebuje besedilo mota, in jo določiti kot prvo vrstico odseka, imenovanega Današnji moto (v programu LibreOfficeWriter pod Vstavi – Odsek). Če je moto spremenjen (in shranjen) v dokument programa LibreOffice Writer, se moto posodobi v vseh celicah programa LibreOffice Calc, v katerih je ta DDE-povezava določena.

## ERRORTYPE

Vrne številko, ki ustreza vrednosti napake, ki se pojavi v neki drugi celici. S pomočjo tega števila lahko prikličete besedilo sporočila o napaki.

Če se pojavi napaka, funkcija vrne logično ali številsko vrednost.

Vrstica stanja prikaže že vnaprej določeno šifro napake iz programa LibreOffice če kliknete na celico, ki vsebuje napako.

#### Skladnja

ERRORTYPE(Sklic)

Sklic vsebuje naslov celice, v kateri se napaka pojavi.

#### Primer

Če celica A1 prikaže Nap:518, funkcija =ERRORTYPE(A1) vrne število 518.

#### Tehnični podatki

Ta funkcija ni del standarda Open Document Format for Office Applications (OpenDocument) Version 1.3. Part 4: Recalculated Formula (OpenFormula) Format. Imenski prostor je

ORG.OPENOFFICE.ERRORTYPE

## GETPIVOTDATA

Funkcija GETPIVOTDATA vrne kot rezultat vrednost iz vrtilne tabele. Sklic na vrednost določajo imena polj in postavk, tako da ostane veljavna tudi ob spremembah postavitve vrtilne tabele.

#### Skladnja

Uporabimo lahko dve različni skladenjski definiciji:

GETPIVOTDATA(ciljno_polje; vrtilna tabela[; polje 1; postavka 1][; ... [polje 126; postavka 126]])

ali

GETPIVOTDATA(vrtilna tabela; omejitve)

Druga skladnja je privzeta, če sta podana natanko dva parametra, kjer je prvi parameter sklic na celico ali obseg celic. V vseh ostalih primerih je privzeta prva skladnja. Čarovnik za funkcije pokaže prvo skladnjo.

### Prva skladnja

Ciljno_polje je niz, s katerim izberemo eno od podatkovnih polj vrtilne tabele. Niz je lahko ime enega od izvornih stolpcev ali pa ime podatkovnega polja v tabeli (npr. »Vsota - Prodaja«).

Vrtilna tabela je sklic na celico ali obseg celic, ki se nahaja v vrtilni tabeli ali vrtilno tabelo vsebuje. Če obseg celic vsebuje več vrtilnih tabel, bo uporabljena nazadnje ustvarjena tabela.

Če ne navedete parov Polje n / postavka n, bo vrnjena celotna vsota. V nasprotnem primeru vsak tak par doda omejitev, ki ji mora rezultat zadoščati. Polje n je ime polja v vrtilni tabeli. Postavka n je ime postavke v tem polju.

Če vrtilna tabela vsebuje en sam rezultat, ki ustreza vsem pogojem, ali pa delno vsoto, ki je seštevek vseh vrednosti, ki ustrezajo, funkcija to vrednost vrne. Če ni ustreznega rezultata ali če jih je več brez ustreznega seštevka, funkcija vrne napako. Ti pogoji veljajo za rezultate, vključene v vrtilno tabelo.

Vnosi vira podatkov, ki so prikriti z nastavitvami vrtilne tabele, so prezrti. Razvrščenost parov polje/postavka ni pomembna. Pri imenih polj in postavk ni razlikovanja med velikimi in malimi črkami.

Če za filter ni navedena omejitev, bo uporabljena izbrana vrednost polja. Če pa je za filter navedena omejitev, mora ustrezati izbrani vrednosti polja, sicer funkcija javi napako. Filtri so polja v levem zgornjem delu vrtilne tabele, zapolnjena s pomočjo območja »Filtri« pogovornega okna Postavitev vrtilne tabele. Z vsakega filtra lahko izberete element (vrednost), kar pomeni, da bo le ta element vključen v izračun.

Delne vsote vrtilne tabele pridejo v poštev, le če uporabljajo funkcijo »samodejno« (razen ko so navedene v sami omejitvi, glejte drugo skladnjo spodaj).

### Druga skladnja

Vrtilna tabela ima isti pomen kot v prvi skladnji.

Omejitve je s presledki ločen seznam. Vnosi so lahko v narekovajih (enojni narekovaji). Celoten niz mora biti zaobjet z narekovaji (dvojni narekovaji), če se ne sklicujete na niz iz druge celice.

Eden od vnosov je lahko ime podatkovnega polja. V primeru, da vrtilna tabela vsebuje eno samo podatkovno polje, ga lahko izpustimo, sicer pa mora biti prisotno.

Vsak od vnosov določa omejitev v obliki Polje[postavka] (z oglatimi oklepaji: [ in ]) ali zgolj Postavka, ko gre za enkratno ime med vsemi polji, uporabljenimi v vrtilni tabeli.

Ime funkcije dodate z zapisom Polje[postavka;funkcija], kar pomeni, da se bo omejitev ujemala le z delnimi vsotami, ki to funkcijo uporabljajo. Možna imena za funkcije so Sum, Count, Average, Max, Min, Product, Count (samo številke), StDev (vzorec), StDevP (populacija), Var (vzorec) in VarP (populacija), brez razlikovanja med velikimi in malimi črkami.

## HLOOKUP

Išče vrednosti in sklic na celice pod izbranim območjem. Ta funkcija preveri če prva vrstica matrike vsebuje določeno vrednost. Funkcija nato vrne vrednost v vrstici matrike, ki je navedena v Kazalu istega stolpca.

Iskanje podpira regularne izraze. Če so ti omogočeni, lahko vnesete npr. »vse.*«, da najdete prvo mesto, kjer se nahaja »vse«, in kateremu sledi karkoli. Če želite iskati besedilo, ki je tudi regularen izraz, morate pred vsak meta-znak regularnega izraza ali operator vnesi znak »\« ali pa besedilo zaobjeti v \Q...\E. Samodejno vrednotenje nadomestnih znakov ali regularnega izraza lahko vklopite in izklopite v LibreOffice – Nastavitve Orodja – Možnosti – LibreOffice Calc – Izračuni.

Če uporabljate funkcije, v katerih je vsaj eden argument iskalni pogoj, ki predstavlja regularni izraz, se bo niz pogojev najprej poskusil pretvoriti v števila. Primer: ».0« se pretvori v 0.0 itn. Če pretvorba uspe, iskanje ne bo vrnilo regularnega izraza, temveč število. Če preklopite na slovenske področne nastavitve, kjer decimalno ločilo ni pika, temveč vejica, pa pretvorba regularnega izraza deluje. Če želite vsiliti iskanje regularnega izraza namesto števila, uporabite izraz, ki ga ni mogoče pretvoriti v numeričnega, npr. ».[0]«, ».\0« ali »(?i).0«.

#### Skladnja

HLOOKUP(iskano; matrika; kazalo [; iskanje_po_razvrščenih_obsegih])

Razlago parametrov si oglejte tukaj: VLOOKUP (stolpci in vrstice so zamenjani).

Obravnava praznih celic

#### Primer

Recimo, da smo izdelali manjšo tabelo zbirke podatkov, ki obsega celice A1:DO4 in vsebuje osnovne podatke o 118 kemijskih elementov. Prvi stolpec vsebuje naslove vrstic »Element«, »Simbol«, »Atomsko število« in »Relativna atomska teža«. Naslednji stolpci vsebujejo relevantne podatke za vsakega od elementov, razvrščenih od leve proti desni z naraščajočim atomskim številom. Primer: celice B1:B4 vsebujejo vrednosti »Vodik«, »H«, »1« in »1,008«, medtem ko celice DO1:DO4 vsebujejo »Oganeson«, »Og«, »118« in »294«.

| A | B | C | D | ... | DO
--- | --- | --- | --- | --- | --- | ---
1 | Element | Vodik | Helij | Litij | ... | Oganeson
2 | Simbol | H | He | Li | ... | Og
3 | Atomsko število | 1 | 2 | 3 | ... | 118
4 | Relativna atomska teža | 1.008 | 4.0026 | 6.94 | ... | 294

=HLOOKUP("Svinec"; $A$1:$DO$4; 2; 0) vrne »Pb«, simbol za svinec.

=HLOOKUP("Zlato"; $A$1:$DO$4; 3; 0) vrne 79, atomsko število zlata.

=HLOOKUP("Ogljik"; $A$1:$DO$4; 4; 0) vrne 12,011,relativno atomsko težo ogljika.

## HYPERLINK

Ko kliknete na celico, ki vsebuje funkcijo HYPERLINK, se odpre hiperpovezava.

Če uporabite neobvezni parameter vrednost_celice, formula poišče URL in prikaže to besedilo ali število.

Če hočete odpreti celico s hiperpovezavo s tipkovnico, stisnite tipko F2, da vstopite v način Uredi, premakneta kazalec miške pred hiperpovezavo, stisnete tipki dvigalka+F10 in potem izberete Odpri hiperpovezavo.

#### Skladnja

HYPERLINK("URL" [; vrednost_celice])

URL določa cilj povezave. Neobvezni parameter vrednost_celice je besedilo ali število, ki se prikaže v celici in se vrne kot rezultat funkcije. Če parameter vrednost_celice ni podan, se URL prikaže v besedilu celice in je vrnjen kot rezultat funkcije.

Število 0 je vrnjeno za prazne celice in elemente matrike.

#### Primer

=HYPERLINK("http://www.primer.org") prikaže besedilo »http://www.primer.org« v celici in izvrši povezavo http://www.primer.org, ko nanjo kliknemo.

=HYPERLINK("http://www.primer.org";"Kliknite tukaj") izpiše besedilo »Kliknite tukaj« v celici in izvrši hiperpovezavo http://www.primer.org, ko nanjo kliknemo.

=HYPERLINK("http://www.primer.org";12345) prikaže število 12345 in izvrši povezavo http://www.primer.org, ko nanjo kliknemo.

=HYPERLINK($B4), kjer celica B4 vsebuje http://www.primer.org. Ta funkcija doda http://www.primer.org k URL-ju celice s hiperpovezavo in vrne isto besedilo, ki ga funkcija uporabi, kot rezultat formule.

=HYPERLINK("http://www.";"Kliknite ") & "primer.org" prikaže besedilo Kliknite primer.org v celici in izvrši hiperpovezavo http://www.primer.org, ko nanjo kliknemo.

=HYPERLINK("#DelovniList1.A1";"Pojdi na vrh") prikaže besedilo Pojdi na vrh in skoči na celico DelovniList1.A1 v tem dokumentu.

=HYPERLINK("file:///C:/writer.odt#Pojasnilo";"Pojdi na zaznamek v dokumentu") prikaže besedilo »Pojdi na zaznamek v dokumentu«, naloži navedeni dokument z besedilom in skoči na zaznamek »Pojasnilo«.

=HYPERLINK("file:///C:/Dokumenti/";"Odpri mapo Dokumenti") prikaže besedilo »Odpri mapo Dokumenti« in prikaže vsebino mape v standardnem upravitelju oz. raziskovalcu datotek vašega operacijskega sistema.

Funkcija poskuša prečiti sistemske posebnosti. Primer: niz "c:\pot do\datoteka.kon" bo ustrezno tolmačen kot "file:///c:/pot%20do/datoteka.kon" na sistemih Windows, ".." pa bo vodil do nadrejene mape dokumenta.

## INDEX

INDEX vrne sklic, vrednost ali polje vrednosti iz referenčnega obsega, podanega z indeksno številko vrstice in stolpca ali poljem številk indeksov vrstic in stolpcev, in neobveznim indeksom obsega.

INDEX() vrne sklic, če je argument en ali več sklicev. Če ga uporabite v celici v obliki =INDEX(), se sklic razreši in izpišejo se njegove vrednosti. Če je INDEX() uporabljen kot argument za druge funkcije, =FUNKCIJA(INDEX()...), bo funkciji podan sklic, ki ga vrne INDEX(). Vrnjeni sklic je drugačen od vrnjenega polja vrednosti za funkcije, ki jih obravnavajo različno.

#### Skladnja

INDEX(sklic [; [vrstica] [; [stolpec] [; obseg]]])

Sklic je sklic na celico, ki ga vnesete neposredno ali pa tako, da navedete ime obsega. Če je sklic sestavljen iz več določenih območij, morate v oklepaju dodati seznam sklicev ali imen obsegov, uporabiti tildo (~), operator za unijo oz. konkatenacijo obsegov ali določiti imenovani obseg z več območji.

Vrstica (neobvezno) predstavlja številko vrstice ali polje številk vrstic v območju sklica, za katero funkcija vrne vrednost. V primeru ničle ali izpusta (nedoločene vrstice) so vrnjene vse sklicane vrstice.

Stolpec (neobvezno) predstavlja številko stolpca ali polje številk stolpcev v obsegu sklica, za katerega funkcija vrne vrednost. V primeru ničle ali izpusta (nedoločen stolpec) so vrnjeni vsi sklicani stolpci.

Če sta Vrstica, Stolpec ali oba izpuščena ali definirana kot polji indeksov, je potrebno funkcijo INDEX vnesti kot matrično funkcijo.

Obseg (neobvezno) predstavlja kazalo podobsega, če se sklicuje na več obsegov, privzeta vrednost je 1.

#### Primer

{=INDEX({1,3,5;7,9,10},{2;1},1)} vrne 2-vrstično polje, ki vsebuje 7 in 1. Številki oz. indeksa vrstic {2;1} izbereta vrstico 2, nato vrstico 1. Indeks oz. številka stolpcev 1 izbere prvi stolpec.

{=INDEX(D3:G12,{1;2;3;4},{3,1})} vrne polje 4 vrstic in 2 stolpcev. Polje številk oz. indeksov vrstic {1;2;3;4} izbere vrstice od 3 do 6 in {3;1} izbere tretji (F) in prvi stolpec (D). Stolpca 1 in 3 izvornega sklica se v končnem polju izmenjata.

=INDEX(Cene;4;1) vrne vrednost, ki je v 4. vrstici in 1. stolpcu obsega zbirke podatkov, ki ga določimo v Podatki – Določi obseg ... kot Cene.

=INDEX(VsotaX;4;1) vrne vrednost iz območja VsotaX iz 4. vrstice in 1. stolpca, kot ga določimo v Delovni list – Imenovani obsegi in izrazi – Določi.

{=INDEX(A1:B6;1)} vrne vrednosti prve vrstice A1:B6. Vnesite formulo kot matrično formulo.

{=INDEX(A1:B6;0;1)} vrne vrednosti prvega stolpca A1:B6. Vnesite formulo kot matrično formulo.

=INDEX(A1:B6;1;1) vrne vrednost iz zgornjega levega kota območja A1:B6.

{=INDEX((A1:B6;C1:D6);0;0;2)} vrne vrednosti drugega obsega C1:D6 izmed več obsegov. Vnesite formulo kot matrično formulo.

Podobne teme

Stran wiki o funkciji INDEX (v angl.).

## INDIRECT

Vrne sklic, ki ga določa besedilni niz. To funkcijo je mogoče uporabiti tudi tako, da vrne območje ustreznega besedila.

Ta funkcija se vedno znova izračuna, ko se izvede ponovno izračunavanje.

Zaradi prenosljivosti funkciji ADDRESS in INDIRECT podpirata neobvezen parameter, ki določa, ali naj bo namesto običajne notacije A1 uporabljena notacija naslavljanja celic V1S1.

Pri ADDRESS je parameter vstavljen kot četrti parameter, ki zamakne neobvezen parameter imena delovnega lista na peti položaj.

Pri INDIRECT je parameter dodan kot drug parameter.

Pri obeh funkcijah velja, da je ob argumentu z vrednostjo 0 uporabljena notacija V1S1. Če argument ni podan ali ima vrednost, različno od 0, je uporabljena notacija A1.

V primeru notacije V1S1 funkcija ADDRESS vrne nize naslovov s klicajem »!« kot ločilom imen delovnih listov, funkcija INDIRECT pa pričakuje klicaj kot ločilo imen delovnih listov. Obe funkciji še vedno uporabljata piko ».« kot ločilo med imeni delovnih listov v notaciji A1.

Ko odpirate dokumente v zapisu ODF 1.0/1.1, bo v funkcijah ADDRESS, ki prikazujejo ime delovnega lista kot četrti parameter, to ime delovnega lista pomaknjeno v peti parameter. Na mesto četrtega parametra bo vstavljena vrednost 1.

Če funkcije ADDRESS uporabljajo četrti parameter, bo pri shranjevanju v zapisu ODF 1.0/1.1 ta parameter odstranjen.

Preglednice ne shranjujte v starem zapisu ODF 1.0/1.1, če ste uporabili novi četrti parameter funkcije ADDRESS z vrednostjo 0.

Funkcija INDIRECT se shrani brez pretvorbe v zapis ODF 1.0/1.1. Če je bil prisoten drug parameter, bo starejša različica modula Calc vrnila za to funkcijo napako.

#### Skladnja

INDIRECT(skl [; A1])

skl predstavlja sklic na celico ali območje (v obliki besedila), za katerega funkcija vrne vsebino.

A1 (neobvezno) – če ima vrednost 0, je uporabljena oblika zapisa V1S1. Če tega parametra ni ali ima drugačno vrednost kot 0, je uporabljena notacija A1.

Če odprete preglednico programa Excel, ki uporablja posredne naslove, izračunane s funkcijami za nize, naslovi delovnega lista ne bodo samodejno prevedeni. Primer: Excelov naslov v INDIRECT("[imedatoteke]imedelovnegalista!"&B1) se ne pretvori v Calcov naslov v INDIRECT("imedatoteke#imedelovnegalista."&B1).

#### Primer

=INDIRECT(A1) vrne 100, če A1 vsebuje C108 kot sklic in celica C108 vsebuje vrednost 100.

=SUM(INDIRECT("a1:" & ADDRESS(1;3))) sešteje celice v območju od A1 do celice, katere naslov je določen s 1. vrstico in 3. stolpcem. Sešteje se torej območje A1:C1.

Podobne teme

Stran wiki o funkciji INDIRECT (v angl.).

## LOOKUP

Vrne vsebino celice iz obsega ene vrstice ali enega stolpca. Dodeljena vrednost (z enakim kazalom) je lahko vrnjena v drugem stolpcu ali vrstici. Za razliko od VLOOKUP in HLOOKUP sta lahko iskalni in rezultatski vektor na drugačnih položajih; ni nujno, da sta sosednja. Poleg tega mora biti iskalni vektor funkcije LOOKUP razvrščen, sicer iskanje ne vrne uporabnih rezultatov.

Če LOOKUP ne najde iskanega pogoja, vrne največjo vrednost iskanega vektorja, ki je manjši ali enak iskanemu pogoju.

Iskanje podpira regularne izraze. Če so ti omogočeni, lahko vnesete npr. »vse.*«, da najdete prvo mesto, kjer se nahaja »vse«, in kateremu sledi karkoli. Če želite iskati besedilo, ki je tudi regularen izraz, morate pred vsak meta-znak regularnega izraza ali operator vnesi znak »\« ali pa besedilo zaobjeti v \Q...\E. Samodejno vrednotenje nadomestnih znakov ali regularnega izraza lahko vklopite in izklopite v LibreOffice – Nastavitve Orodja – Možnosti – LibreOffice Calc – Izračuni.

Če uporabljate funkcije, v katerih je vsaj eden argument iskalni pogoj, ki predstavlja regularni izraz, se bo niz pogojev najprej poskusil pretvoriti v števila. Primer: ».0« se pretvori v 0.0 itn. Če pretvorba uspe, iskanje ne bo vrnilo regularnega izraza, temveč število. Če preklopite na slovenske področne nastavitve, kjer decimalno ločilo ni pika, temveč vejica, pa pretvorba regularnega izraza deluje. Če želite vsiliti iskanje regularnega izraza namesto števila, uporabite izraz, ki ga ni mogoče pretvoriti v numeričnega, npr. ».[0]«, ».\0« ali »(?i).0«.

#### Skladnja

LOOKUP (iskano; iskalni_vektor [; rezultatski_vektor])

Iskano je vrednost poljubne vrste, ki jo želimo najti; vnesemo jo neposredno ali kot sklic.

Iskalni_vektor je enovrstično ali enostolpično območje, ki ga želimo preiskati.

Rezultatski_vektor je še eno enovrstično ali enostolpčno območje, v katerem funkcija najde rezultat. Rezultat je celica rezultatskega vektorja, ki ima isti indeks kot pri iskalnem vektorju.

Obravnava praznih celic

#### Primer

=LOOKUP(A1;D1:D100;F1:F100) v obsegu D1:D100 išče ustrezno celico s številom, ki ste ga vnesli v A1. Za najdene primere določi kazalo, npr. 12. celica v tem območju. Nato funkcija vrne vsebino 12. celice kot vrednost funkcije (v rezultatskem vektorju).

## MATCH

Vrne relativni položaj predmeta v matriki, ki ustreza določeni vrednosti. Funkcija vrne položaj vrednosti, ki jo najde v iskalni matriki, v obliki števila.

#### Skladnja

MATCH (iskano, iskalna_matrika [; vrsta])

Iskano je vrednost, ki jo želimo najti v enovrstični ali enostolpčni matriki.

Iskalna_matrika je sklic na območje, ki ga želimo preiskati. Iskalna matrika je lahko ena vrstica ali stolpec oz. del vrstice ali stolpca.

Vrsta lahko zavzame vrednosti 1, 0 ali -1. Če je Vrsta = 1 ali pa ta neobvezni parametere manjka, funkcija domneva, da je prvi stolpec iskalnega polja razvrščen naraščajoče. Če je Vrsta = -1, funkcija domneva, da je stolpec razvrščen padajoče. Ta funkcija deluje tako kot ista funkcija v programu Microsoft Excel.

Če je vrsta enaka 0, funkcija najde le natančne zadetke. Če funkcija iskalni pogoj najde na več mestih, vrne indeks prvega, ki ga najde. Le če vnesemo vrsta = 0, lahko iščemo z regularnimi izrazi (če so omogočeni v nastavitvah izračunov) in nadomestnimi znaki (če so omogočeni v nastavitvah izračunov).

Če je vrsta enaka 1 ali če tretji parameter izpustimo, funkcija vrne indeks zadnje vrednosti, ki je manjša ali enaka iskalnemu pogoju. Če je vrsta enaka -1, funkcija vrne indeks zadnje vrednosti, ki je večja ali enaka.

Iskanje podpira regularne izraze. Če so ti omogočeni, lahko vnesete npr. »vse.*«, da najdete prvo mesto, kjer se nahaja »vse«, in kateremu sledi karkoli. Če želite iskati besedilo, ki je tudi regularen izraz, morate pred vsak meta-znak regularnega izraza ali operator vnesi znak »\« ali pa besedilo zaobjeti v \Q...\E. Samodejno vrednotenje nadomestnih znakov ali regularnega izraza lahko vklopite in izklopite v LibreOffice – Nastavitve Orodja – Možnosti – LibreOffice Calc – Izračuni.

Če uporabljate funkcije, v katerih je vsaj eden argument iskalni pogoj, ki predstavlja regularni izraz, se bo niz pogojev najprej poskusil pretvoriti v števila. Primer: ».0« se pretvori v 0.0 itn. Če pretvorba uspe, iskanje ne bo vrnilo regularnega izraza, temveč število. Če preklopite na slovenske področne nastavitve, kjer decimalno ločilo ni pika, temveč vejica, pa pretvorba regularnega izraza deluje. Če želite vsiliti iskanje regularnega izraza namesto števila, uporabite izraz, ki ga ni mogoče pretvoriti v numeričnega, npr. ».[0]«, ».\0« ali »(?i).0«.

#### Primer

=MATCH(200;D1:D100) v območju D1:D100, ki je razvrščeno po stolpcu D, išče vrednost 200. Kakor hitro naleti na to vrednost, funkcija vrne številko vrstice, v kateri se nahaja. Če funkcija med iskanjem v stolpcu naleti na višjo vrednost, vrne številko prejšnje vrstice.

## OFFSET

Vrne odmik celice, ki je bil z začetne točke premaknjen za določeno število vrstic in stolpcev.

Ta funkcija se vedno znova izračuna, ko se izvede ponovno izračunavanje.

#### Skladnja

OFFSET(sklic; vrstice; stolpci [; višina [; širina]])

Sklic je sklic na celico, iz katere funkcija išče nov sklic.

Vrstice je število celic, za katere je sklic bil popravljen navzgor (negativna vrednost) ali navzdol.

Stolpci (neobvezno) je število stolpcev, za katere je sklic bil popravljen v levo (negativna vrednost) ali v desno.

Višina (neobvezno) je navpična višina območja, ki se začne na novi sklicni točki.

Širina (neobvezno) je vodoravna širina območja, ki se začne na novi sklicni točki.

Argumenta vrstice in stolpci ne smeta voditi k ničelni ali negativni začetni vrstici ali začetnemu stolpcu.

Argumenta višina in širina ne smeta voditi k ničelnemu ali negativnemu številu vrstic ali stolpcev.

V funkcijah LibreOffice Calc lahko parametre, ki niso označeni kot »zahtevani«, izpustite le tedaj, ko ne sledi noben parameter. Če sta npr. za funkcijo s štirimi parametri prva dva označena kot »zahtevano«, lahko izpustite parameter 4 ali parametra 3 in 4, ne smete pa izpustiti zgolj parametra 3.

#### Primer

=OFFSET(A1;2;2) vrne vrednost, ki se nahaja v celici C3 (A1 premaknjena za dve vrstici in dva stolpca navzdol). Če C3 vsebuje vrednost 100, ta funkcija vrne vrednost 100.

=OFFSET(B2:C3;1;1) vrne sklic na B2:C3, pomaknjen navzdol za 1 vrstico in za en stolpec na desno (C3:D4).

=OFFSET(B2:C3;-1;-1) vrne sklic na B2:C3, premaknjen navzgor za 1 vrstico in en stolpec na levo (A1:B2).

=OFFSET(B2:C3;0;0;3;4) vrne sklic na B2:C3 s spremenjeno velikostjo na 3 vrstice in 4 stolpce (B2:E4).

=OFFSET(B2:C3;1;0;3;4) vrne sklic na B2:C3, pomaknjen navzdol za eno vrstico in s spremenjeno velikostjo na 3 vrstice in 4 stolpce (B3:E5).

=SUM(OFFSET(A1;2;2;5;6)) izračuna vsoto območja, ki se začne v celici C3 in je visoko 5 vrstic ter široko 6 stolpcev, tj. območje C3:H7.

Če sta podana širina ali višina, funkcija OFFSET vrne sklic na obseg celic. Če je sklic sklic na posamezno celico in sta širina in višina izpuščena, vrne sklic na posamezno celico.

## ROW

Vrne številko vrstice sklica. Če je sklic celica, funkcija vrne številko vrstice, v kateri je celica. Če je sklic obseg celic, funkcija vrne ustrezne številke vrstic v enostolpični matriki, če formulo vnesemo kot matrično formulo. Če funkcije ROW s sklicem na obseg ne uporabimo kot matrično formulo, bo vrnila le številko vrstice prvega obsega celic.

#### Skladnja

ROW([sklic])

Sklic je celica, območje ali ime območja.

Če sklica ne navedemo, funkcija vrne številko vrstice tiste celice, v kateri je formula. LibreOffice Calc samodejno nastavi sklic na trenutno celico.

#### Primer

=ROW(B3) vrne 3, ker se sklic nanaša na tretjo vrstico v tabeli.

{=ROW(D5:D8)} vrne enostolpično matriko (5, 6, 7, 8), ker navedeni sklic zajema vrstice od 5 do 8.

=ROW(D5:D8) vrne 5, ker funkcije ROW nismo uporabili kot matrične formule, zato vrne le številko prve vrstice sklica.

{=ROW(A1:E1)} in =ROW(A1:E1) obe vrneta 1, ker sklic vsebuje le vrstico 1 kot prvi stolpec v tabeli (ker imajo enovrstična območja le eno številko vrstice, je vseeno, če je formula uporabljena kot matrična formula ali ne).

=ROW() vrne 3, če formulo vnesemo v 3. vrstico.

{=ROW(Zajec)} vrne enosvrstično matriko (1, 2, 3), če je »Zajec« ime območja (C1:D3).

## ROWS

Vrne število vrstic v sklicu ali matriki.

#### Skladnja

ROWS(matrika)

Matrika je sklic ali imenovano območje, katerega skupno število vrstic želimo določiti.

#### Primer

=Rows(B5) vrne 1, ker celica obsega le eno vrstico.

=ROWS(A10:B12) vrne 3.

=ROWS(Zajec) vrne 3, če je »Zajec« ime območja (C1:D3).

## SHEET

Vrne številko delovnega lista s sklicem ali nizom, ki predstavlja ime delovnega lista. Če ne vnesemo nobenih parametrov, je rezultat številka delovnega lista dokumenta s preglednico, ki vsebuje formulo.

#### Skladnja

SHEET([Sklic])

Sklic je neobvezen parameter in pomeni sklic na celico, območje ali ime delovnega lista.

#### Primer

=SHEET(DelovniList2.A1) vrne 2, če je DelovniList2 drugi delovni list po vrsti v preglednici.

=SHEET(DelovniList3) vrne 3, če je DelovniList3 tretji delovni list po vrsti v preglednici.

## SHEETS

Določi število delovnih listov v sklicu. Če ne vnesemo nobenih parametrov, vrne število delovnih listov v trenutnem dokumentu.

#### Skladnja

SHEETS([Sklic])

Sklic je sklic na delovni list ali območje. Ta parameter je neobvezen.

#### Primer

=SHEETS(DelovniList1.A1:DelovniList3.G12) vrne 3, če so DelovniList1, DelovniList2 in DelovniList3 v navedenem zaporedju.

## VLOOKUP

Navpično iskanje s sklicem na sosednje celice na desni. Ta funkcija preverja, če se v prvem stolpcu matrike nahaja določena vrednost. Funkcija potem vrne vrednost, ki se nahaja v isti vrstici, in sicer v stolpcu, ki ga navedete v kazalu. Če je parameter razvrščeno izpuščen ali nastavljen na TRUE, se privzame, da gre za podatke, ki so razvrščeni v naraščajočem vrstnem redu. Če iskanemu natanko enaka vrednost ni najdena, funkcija vrne zadnjo vrednost, ki je bila manjša od iskane. Če nastavite razvrščeno na FALSE ali na nič, funkcija najde točno isto vrednost, ali pa vrne kot rezultat napako Napaka: vrednost ni na voljo. Zato pri vrednosti nič ni potrebno, da so podatki razvrščeni v naraščajočem vrstnem redu.

Iskanje podpira regularne izraze. Če so ti omogočeni, lahko vnesete npr. »vse.*«, da najdete prvo mesto, kjer se nahaja »vse«, in kateremu sledi karkoli. Če želite iskati besedilo, ki je tudi regularen izraz, morate pred vsak meta-znak regularnega izraza ali operator vnesi znak »\« ali pa besedilo zaobjeti v \Q...\E. Samodejno vrednotenje nadomestnih znakov ali regularnega izraza lahko vklopite in izklopite v LibreOffice – Nastavitve Orodja – Možnosti – LibreOffice Calc – Izračuni.

Če uporabljate funkcije, v katerih je vsaj eden argument iskalni pogoj, ki predstavlja regularni izraz, se bo niz pogojev najprej poskusil pretvoriti v števila. Primer: ».0« se pretvori v 0.0 itn. Če pretvorba uspe, iskanje ne bo vrnilo regularnega izraza, temveč število. Če preklopite na slovenske področne nastavitve, kjer decimalno ločilo ni pika, temveč vejica, pa pretvorba regularnega izraza deluje. Če želite vsiliti iskanje regularnega izraza namesto števila, uporabite izraz, ki ga ni mogoče pretvoriti v numeričnega, npr. ».[0]«, ».\0« ali »(?i).0«.

#### Skladnja

=VLOOKUP(iskano; matrika; kazalo [; iskanje_po_razvrščenih_obsegih])

Iskano je vrednost poljubne vrste, ki jo iščemo v prvem stolpcu matrike.

Matrika je sklic, ki mora obsegati vsaj toliko stolpcev, kolikor jih je številsko podanih v argumentu Kazalo.

Kazalo je številka stolpca v matriki, ki vsebuje vrednost, ki jo mora funkcija vrniti. Prvi stolpec ima številko 1.

Iskanje_po_razvrščenih_obsegih je neobvezen parameter in določa, ali prvi stolpec matrike vsebuje meje obsega namesto samih vrednosti, ter vrne vrednost v tisti vrstici, v kateri ima prvi stolpec vrednost enako ali večjo kot iskano. Primer: matrika vsebuje datume, na katere se je davek spremenil, torej vrednosti predstavljajo začetne datume obdobja, ko je veljala določena davčna obveznost. Iskanje datuma, ki ga ni v prvem stolpcu matrike, pade pa med obstoječa mejna datuma, vrne tisti datum, ki je bližji. Tako lahko najdemo podatke, ki so veljali na iskani datum. Vnesite logično vrednost FALSE ali ničlo, če prvi stolpec ne vsebuje seznama meja obsega. Če je ta parameter TRUE ali ni podan, mora biti prvi stolpec matrike razvrščen v naraščajočem vrstnem redu. Po razvrščenih stolpcih je iskanje veliko hitrejše in funkcija vedno vrne vrednost, tudi če ni mogoče najti iskane vrednosti, če je le večja od najnižje vrednosti na razvrščenem seznamu. Če seznam ni razvrščen, bo iskanje vrnilo le natančno iskano vrednost. Če ta ne obstaja, funkcija vrne #N/A s sporočilom: Napaka: vrednost ni na voljo.

Obravnava praznih celic

#### Primer

Recimo, da želite vnesti številko jedi na jedilniku (v celico A1) in želite, da se ime jedi v obliki besedila takoj pojavi v sosednji celici (B1). Število, s katerim poimenujemo dodelitev, se nahaja v matriki D1:E100. D1 vsebuje 100, E1 vsebuje ime Zelenjavna juha, in tako naprej, za 100 točk jedilnika. Številke v stolpcu D so razvrščene naraščajoče, zato izbirni parameter iskanje_po_razvrščenih_obsegih ni potreben.

Vnesite naslednjo formulo v B1:

=VLOOKUP(A1;D1:E100;2)

Takoj ko boste vnesli število v A1, se bo v B1 prikazalo ustrezno besedilo, ki ga vsebuje drugi stolpec sklica D1:E100. Če vnesete neobstoječe število, se prikaže besedilo, ki se nahaja pod naslednjim številom. Če želite to preprečiti, vnesite FALSE kot zadnji parameter v formuli, v tem primeru se bo, če boste vnesli neobstoječe število, izpisalo sporočilo o napaki.

Podobne teme

Seznam funkcij po kategorijah